# SWEA 3D Distributions into Phase Space Density

Version: 2021-05-13

The IMPACT investigation’s SWEA sensor produces 3D suprathermal electron distribution functions in the energy range between about ~45 eV and 3 keV. In the IMPACT Level 1 data, these distributions are in raw counts obtained in the energy ranges given in Table 1 and in 80 look directions. SWEA is operated primarily in two modes (mode 0 and mode 1). Mode 0 predominates throughout the mission while mode 1 was used for about a year in 2008 – 2009. Mode 1 was used to remove some of the excess counts at low energies due to instrument charging. However it was later determined that these lower energy counts could still be used to approximate some solar wind characteristics. The mode ID number is provided in the SWEA Level 1 dataset. A map of the look directions is provided in Table 2 and is to be mapped over the entire 360-degree field of view. The Sun is along the symmetry axis at the meeting point of angle bins 0 through 7. When the spacecraft was flipped at solar conjunction, the Sun direction did not change as it was still along the symmetry axis. However, the angle bins were rotated 180 degrees around the Sun – spacecraft line.

The SWEA team at IRAP, Toulouse converts these data into phase space density to produce Level 2 pitch angle distributions for each of the energy ranges. The algorithm by which this conversion to phase space density is performed we describe here.

|  |  |  |
| --- | --- | --- |
| Channel | Mode 0 | Mode 1 |
| 0 | 1347.08 – 2188.10 eV | 1498.46 – 2131.46 eV |
| 1 | 829.31 – 1347.08 eV | 1053.44 – 1498.46 eV |
| 2 | 510.56 – 829.31 eV | 740.59 – 1053.44 eV |
| 3 | 314.32 – 510.56 eV | 520.65 – 740.59 eV |
| 4 | 193.51 – 314.32 eV | 366.02 – 520.65 eV |
| 5 | 119.13 – 193.51 eV | 257.33 – 366.02 eV |
| 6 | 73.34 – 119.13 eV | 180.90 – 257.33 eV |
| 7 | 45.15 – 73.34 eV | 127.18 – 180.90 eV |
| 8 | 27.80 – 45.15 eV | 89.41 – 127.18 eV |
| 9 | 17.11 – 27.80 eV | 62.86 – 89.41 eV |
| 10 | 10.54 – 17.11 eV | 44.19 – 62.66 eV |
| 11 | 6.49 – 10.54 eV | 31.06 – 44.19 eV |
| 12 | 3.99 – 6.49 eV | 21.84 – 31.06 eV |
| 13 | 2.46 – 3.99 eV | 15.35 – 21.84 eV |
| 14 | 1.51 – 2.46 eV | 10.79 – 15.35 eV |
| 15 | 0.93 – 1.51 eV | 7.59 – 10.79 eV |

Table 1: Energy ranges of SWEA energy channels for modes 0 and 1. Note that the channels below 45 eV are dominated by electrons from internal charging of the instrument and so should generally be ignored except in very special circumstances.

|  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
| 0 | 0 | 1 | 1 | 2 | 2 | 3 | 3 | 4 | 4 | 5 | 5 | 6 | 6 | 7 | 7 |
| 8 | 9 | 10 | 11 | 12 | 13 | 14 | 15 | 16 | 17 | 18 | 19 | 20 | 21 | 22 | 23 |
| 24 | 25 | 26 | 27 | 28 | 29 | 30 | 31 | 32 | 33 | 34 | 35 | 36 | 37 | 38 | 39 |
| 40 | 41 | 42 | 43 | 44 | 45 | 46 | 47 | 48 | 49 | 50 | 51 | 52 | 53 | 54 | 55 |
| 56 | 57 | 58 | 59 | 60 | 61 | 62 | 63 | 64 | 65 | 66 | 67 | 68 | 69 | 70 | 71 |
| 72 | 72 | 73 | 73 | 74 | 74 | 75 | 75 | 76 | 76 | 77 | 77 | 78 | 78 | 79 | 79 |

Table 2: Angle bin map for SWEA’s 80 look directions

# Overview

## Heritage

SWEA had substantial heritage in the WIND 3DPe instrument (Lin et al., 1995) and the FAST Electron ElectroStatic Analyzer (EESA) (Carlson et al., 2001). In particular, these represented the early stages of development of the 3D capability with the eventual adoption of ‘top-hat’ designs for the analyzers. We have made use of existing code originally written for the Wind/3DP instrument for data visualization. This code originally known as TPLOT was updated and included in the Themis mission’s TDAS/SPEDAS library.

## Product Description

SWEA was originally designed to measure electrons with energies between 1 eV and 3 keV. The instrument’s field of view is 360 X 120 degrees and has a dynamic range of about 10^8 eV/(cm^2 \* sr \* eV \* s). Sauvaud et al. (2008), provided a complete description of the instrument as flown. Once in heliocentric orbit, it was found that the shadowing environment of SWEA on the end of the IMPACT boom, which permanently extends into the antisolar spacecraft wake (STEREO’s stabilized orientation is controlled by its sunward-pointing imagers), resulted in interior charging that limited the use of SWEA below ~45 eV. Thus the suprathermal electrons (>45 eV) are routinely measured as planned, but information about the thermal electron population requires special treatment (see Fedorov et al., 2011). The latter are not routinely executed or processed as data products-and thus not described here.

The >45 eV 3D distributions produced by SWEA are reported in 16 energy bins and 80 angle bins. The algorithm described takes the raw data in an array of (16,80) from raw counts to produce phase space density in these energy and angle bins:

The energy bins are defined by the following lines of IDL code:

;SWEA Mode ID = 0

;

;Min energy of energy bin (in eV)
 E[\*,0,0] = [ 1347.08, 829.31, 510.56, 314.32, 193.51, 119.13, 73.34, 45.15, 27.80, 17.11, 10.54, 6.49, 3.99, 2.46, 1.51, 0.93 ]

;Center of energy bin (in eV)

 E[\*,1,0] = [ 1716.84, 1056.95, 650.70, 400.60, 246.62, 151.83, 93.47, 57.54, 35.43, 21.81, 13.43, 8.27, 5.09, 3.13, 1.93, 1.19 ]

;Max energy of energy bin (in eV)

 E[\*,2,0] = [ 2188.10, 1347.08, 829.31, 510.56, 314.32, 193.51, 119.13, 73.34, 45.15, 27.80, 17.11, 10.54, 6.49, 3.99, 2.46, 1.51 ]

;SWEA Mode ID=1

;Min energy of energy bin (in eV)

 E[\*,0,1] = [ 1498.46, 1053.44, 740.59, 520.65, 366.02, 257.33, 180.90, 127.18, 89.41, 62.86, 44.19, 31.06, 21.84, 15.35, 10.79, 7.59 ]

;Center of energy bin (in eV)

 E[\*,1,1] = [ 1787.15, 1256.40, 883.27, 620.96, 436.54, 306.90, 215.76, 151.68, 106.63, 74.97, 52.70, 37.05, 26.04, 18.31, 12.87, 9.05 ]

;Max of energy bin (in eV)

 E[\*,2,1] = [ 2131.46, 1498.46, 1053.44, 740.59, 520.65, 366.02, 257.33, 180.90, 127.18, 89.41, 62.86, 44.19, 31.06, 21.84, 15.35, 10.79 ]

Likewise, the angle bin look directions are defined by:

solid = [ [0L, 8,24,40,56,72], $

 [ 0, 9,25,41,57,72], $

 [ 1,10,26,42,58,73], $

 [ 1,11,27,43,59,73], $

 [ 2,12,28,44,60,74], $

 [ 2,13,29,45,61,74], $

 [ 3,14,30,46,62,75], $

 [ 3,15,31,47,63,75], $

 [ 4,16,32,48,64,76], $

 [ 4,17,33,49,65,76], $

 [ 5,18,34,50,66,77], $

 [ 5,19,35,51,67,77], $

 [ 6,20,36,52,68,78], $

 [ 6,21,37,53,69,78], $

 [ 7,22,38,54,70,79], $

 [ 7,23,39,55,71,79]]

# Theoretical Description

SWEA 3D distribution data are transmitted from the spacecraft in log-compressed counts. The exact format of the SWEA data packets and the log compression are given in the IMPACT Command and Telemetry Database: <http://sprg.ssl.berkeley.edu/impact/peters/IMPACT_CTM.xls>

These data can be converted into physical units, specifically phase space density, using the following methodology. Note that SWEA Level 2 pitch angle distributions provided by the SWEA team are already converted to these units. Only the raw Level 1 counts should be handled in this way. All code below is in IDL, and the full code is given just after this explanation.

Phase space density is calculated using the following formula:

; PHASE SPACE DENSITY in sec^3 / km^6

psd[iaz,iel,ie,iline] = raw \* MASS \* MASS \* 1e18 / (dt \* eff \* fg \* 2 \* E \* E \* EV \* EV)

where psd is the phase space density in s^3 / km^6 in an array of 16 azimuth angles (iaz), 6 elevation angles (iel), 16 energies (ie). Iline is data point or “record” index for a particular measurement.

raw is the raw SWEA 3D distribution counts

MASS is the mass of the electron (9.1095 \* 10^31 kg)

dt is the accumulation time for each analyzer step (5.8 ms \* 3), multiplied by 3 because the analyzer steps in 48 energies and is reduced to 16 energies onboard the spacecraft

eff is the efficiency of the detector which is the product of an azimuth and elevation angle-dependent efficiency and an energy-dependent transmission function. These values were determined in calibrations on the ground (angle component) and in flight (energy component due to the SWEA charging phenomenon discovered after launch).

fg is the geometric factor which was determined pre flight to be 5\*10^-4 cm^2 \* sr \* ( eV / eV). In flight it was found that this value must be divided by 1.6 for the SWEA instrument on the Behind spacecraft.

E is the (average) energy of each energy bin given in tables in the section above

EV is the value of the electron volt expressed in Joules (1.602176 \* 10^-19)

Following is the complete code used by IRAP to produce phase space density from raw counts:

;-------------------------------------------------------------------------------

FUNCTION get\_swea\_energy

;-------------------------------------------------------------------------------

; Return energy table

; - table 0: from 1.51 to 1347.08 eV

; - table 1: from 10.79 to 1498.46 eV

;-------------------------------------------------------------------------------

 nbtables = 2L

 nbenergies = 16

 E = REPLICATE (0.,nbenergies,3,nbtables)

 E[\*,0,0] = [ 1347.08, 829.31, 510.56, 314.32, 193.51, 119.13, 73.34, 45.15, 27.80, 17.11, 10.54, 6.49, 3.99, 2.46, 1.51, 0.93 ]

 E[\*,1,0] = [ 1716.84, 1056.95, 650.70, 400.60, 246.62, 151.83, 93.47, 57.54, 35.43, 21.81, 13.43, 8.27, 5.09, 3.13, 1.93, 1.19 ]

 E[\*,2,0] = [ 2188.10, 1347.08, 829.31, 510.56, 314.32, 193.51, 119.13, 73.34, 45.15, 27.80, 17.11, 10.54, 6.49, 3.99, 2.46, 1.51 ]

 E[\*,0,1] = [ 1498.46, 1053.44, 740.59, 520.65, 366.02, 257.33, 180.90, 127.18, 89.41, 62.86, 44.19, 31.06, 21.84, 15.35, 10.79, 7.59 ]

 E[\*,1,1] = [ 1787.15, 1256.40, 883.27, 620.96, 436.54, 306.90, 215.76, 151.68, 106.63, 74.97, 52.70, 37.05, 26.04, 18.31, 12.87, 9.05 ]

 E[\*,2,1] = [ 2131.46, 1498.46, 1053.44, 740.59, 520.65, 366.02, 257.33, 180.90, 127.18, 89.41, 62.86, 44.19, 31.06, 21.84, 15.35, 10.79 ]

 RETURN, E

END

;-------------------------------------------------------------------------------

FUNCTION get\_swea\_efficency, nosat, notable, nbaz, nbel, nbe

;-------------------------------------------------------------------------------

; Return efficency

;-------------------------------------------------------------------------------

 efficency = REPLICATE (1d,nbaz,nbel,nbe)

 IF nosat EQ 1 THEN BEGIN

 efficency1 = [ $

 [ 0.84, 0.92, 0.98, 0.89, 0.90, 0.95, 0.91, 0.81, 0.99, 1.00, 0.90, 0.84, 0.84, 0.85, 0.82, 0.76 ], $

 [ 0.84, 0.92, 0.98, 0.89, 0.90, 0.95, 0.91, 0.81, 0.99, 1.00, 0.90, 0.84, 0.84, 0.85, 0.82, 0.76 ], $

 [ 0.84, 0.92, 0.98, 0.89, 0.90, 0.95, 0.91, 0.81, 0.99, 1.00, 0.90, 0.84, 0.84, 0.85, 0.82, 0.76 ], $

 [ 0.84, 0.92, 0.98, 0.89, 0.90, 0.95, 0.91, 0.81, 0.99, 1.00, 0.90, 0.84, 0.84, 0.85, 0.82, 0.76 ], $

 [ 0.84, 0.92, 0.98, 0.89, 0.90, 0.95, 0.91, 0.81, 0.99, 1.00, 0.90, 0.84, 0.84, 0.85, 0.82, 0.76 ], $

 [ 0.84, 0.92, 0.98, 0.89, 0.90, 0.95, 0.91, 0.81, 0.99, 1.00, 0.90, 0.84, 0.84, 0.85, 0.82, 0.76 ] $

 ]

 END ELSE IF nosat EQ 2 THEN BEGIN

 efficency1 = [ $

 [ 0.82, 0.86, 0.88, 0.84, 0.88, 0.95, 0.90, 0.81, 0.89, 0.95, 0.92, 0.81, 0.99, 1.00, 0.96, 0.80 ], $

 [ 0.82, 0.86, 0.88, 0.84, 0.88, 0.95, 0.90, 0.81, 0.89, 0.95, 0.92, 0.81, 0.99, 1.00, 0.96, 0.80 ], $

 [ 0.82, 0.86, 0.88, 0.84, 0.88, 0.95, 0.90, 0.81, 0.89, 0.95, 0.92, 0.81, 0.99, 1.00, 0.96, 0.80 ], $

 [ 0.82, 0.86, 0.88, 0.84, 0.88, 0.95, 0.90, 0.81, 0.89, 0.95, 0.92, 0.81, 0.99, 1.00, 0.96, 0.80 ], $

 [ 0.82, 0.86, 0.88, 0.84, 0.88, 0.95, 0.90, 0.81, 0.89, 0.95, 0.92, 0.81, 0.99, 1.00, 0.96, 0.80 ], $

 [ 0.82, 0.86, 0.88, 0.84, 0.88, 0.95, 0.90, 0.81, 0.89, 0.95, 0.92, 0.81, 0.99, 1.00, 0.96, 0.80 ] $

 ]

 END

 efficency1[\*,0] \*= 0.65

 IF notable EQ 0 THEN BEGIN

 ;E[\*,0,0] = [ 1347.08, 829.31, 510.56, 314.32, 193.51, 119.13, 73.34, 45.15, 27.80, 17.11, 10.54, 6.49, 3.99, 2.46, 1.51, 0.93 ]

 ;E[\*,1,0] = [ 1716.84, 1056.95, 650.70, 400.60, 246.62, 151.83, 93.47, 57.54, 35.43, 21.81, 13.43, 8.27, 5.09, 3.13, 1.93, 1.19 ]

 ;E[\*,2,0] = [ 2188.10, 1347.08, 829.31, 510.56, 314.32, 193.51, 119.13, 73.34, 45.15, 27.80, 17.11, 10.54, 6.49, 3.99, 2.46, 1.51 ]

 transmission = [1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 0.9, 0.5, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0]

 END ELSE BEGIN

 ;E[\*,0,1] = [ 1498.46, 1053.44, 740.59, 520.65, 366.02, 257.33, 180.90, 127.18, 89.41, 62.86, 44.19, 31.06, 21.84, 15.35, 10.79, 7.59 ]

 ;E[\*,1,1] = [ 1787.15, 1256.40, 883.27, 620.96, 436.54, 306.90, 215.76, 151.68, 106.63, 74.97, 52.70, 37.05, 26.04, 18.31, 12.87, 9.05 ]

 ;E[\*,2,1] = [ 2131.46, 1498.46, 1053.44, 740.59, 520.65, 366.02, 257.33, 180.90, 127.18, 89.41, 62.86, 44.19, 31.06, 21.84, 15.35, 10.79 ]

 transmission = [1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0, 0.9, 0.5, 0.0, 0.0, 0.0, 0.0]

 END

 transmission[WHERE(transmission EQ 0.5)] = 0.0 ; to remove data with E < 45 eV

 FOR ienergie=0L,nbe-1 DO BEGIN

 IF transmission[ienergie] NE 0 THEN BEGIN

 efficency[\*,\*,ienergie] = efficency1\*transmission[ienergie]

 END ELSE BEGIN

 efficency[\*,\*,ienergie] = -1E31

 END

 END

 RETURN, efficency

END

;-------------------------------------------------------------------------------

FUNCTION get\_swea\_geom\_factor, nosat, nbaz, nbel, nbe

;-------------------------------------------------------------------------------

; Return geom\_factor in cm2.sr.(eV/eV)

;-------------------------------------------------------------------------------

 G = DBLARR(nbaz,nbel,nbe) ; geometric factor

 G[\*,\*,\*] = 5e-4

 IF nosat EQ 2 THEN BEGIN

 G /= 1.6 ; Andrea le 06/04/2009 (Pasadena report SWG 2009)

 END

 RETURN, G

END

;-------------------------------------------------------------------------------

PRO stereo\_swea\_convert

;-------------------------------------------------------------------------------

 nbaz = 16

 nbel = 6

 nbe = 16

 filename = '/DATA/STEREO/DATA/l1data/ahead/swea/2008/02/STA\_L1\_SWEA\_DIST\_20080213\_V02.cdf'

 ; 20080213: table==0

 ;filename = '/DATA/STEREO/DATA/l1data/ahead/swea/2008/02/STA\_L1\_SWEA\_DIST\_20080214\_V02.cdf'

 ; 20080214: table==0 and table==1

 ;filename = '/DATA/STEREO/DATA/l1data/ahead/swea/2008/02/STA\_L1\_SWEA\_DIST\_20080215\_V02.cdf'

 ; 20080215: table==1

 nosat = STRMID(FILE\_BASENAME(filename),2,1) EQ 'A' ? 1 : 2

 distribution\_varname = 'Distribution'

 notable\_varname = 'SWEAModeID'

 ;energy\_varname = 'Energy'

 ; Read cdf

 fd = CDF\_OPEN (filename)

 tmp = CDF\_VARINQ (fd, distribution\_varname, /zvar)

 CDF\_CONTROL, fd, variable=distribution\_varname,/zvar,get\_var\_info=vinfo

 nblines = vinfo.maxrec + 1

 CDF\_VARGET, fd, distribution\_varname, distribution, REC\_COUNT=nblines, /zvariable

 CDF\_VARGET, fd, notable\_varname, notable, REC\_COUNT=nblines, /zvariable

 ;CDF\_VARGET, fd, energy\_varname, energy\_table, /zvariable

 CDF\_CLOSE, fd

 notable = REFORM (notable)

 solid = [ [0L, 8,24,40,56,72], $

 [ 0, 9,25,41,57,72], $

 [ 1,10,26,42,58,73], $

 [ 1,11,27,43,59,73], $

 [ 2,12,28,44,60,74], $

 [ 2,13,29,45,61,74], $

 [ 3,14,30,46,62,75], $

 [ 3,15,31,47,63,75], $

 [ 4,16,32,48,64,76], $

 [ 4,17,33,49,65,76], $

 [ 5,18,34,50,66,77], $

 [ 5,19,35,51,67,77], $

 [ 6,20,36,52,68,78], $

 [ 6,21,37,53,69,78], $

 [ 7,22,38,54,70,79], $

 [ 7,23,39,55,71,79]]

 sector = [ [ 2L, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2], $

 [ 2, 1, 1, 1, 1, 2]]

 count = REPLICATE (-1e31, nbaz, nbel, nbe, nblines)

 psd = REPLICATE (-1e31, nbaz, nbel, nbe, nblines)

 FOR iline=0,nblines-1 DO BEGIN

 energy = get\_swea\_energy()

 dt = 5.8E-3 ; en sec (doc de Dave Curtis "SWEA UCB to CESR Interface Control Document")

 ; validÃ© par Peter Schroder Ã  Toulouse le 30 avril 2007

 ; 27/10/2008: Andrei et Andrea dÃ©couvrent que 5.8E-3 est valable pour le mode 48E

 ; D'aprÃ©s eux, je dois utiliser une valeur 3 fois plus grande pour les modes Ã  16E

 dt \*= 3.0

 geom\_factor = get\_swea\_geom\_factor (nosat,nbaz,nbel,nbe) ; in cm2.sr.(eV/eV)

 geom\_factor \*= 1e-4 ; cm2.sr.(eV/eV) -> m2.sr.(eV/eV)

 efficency = get\_swea\_efficency (nosat, notable[iline], nbaz, nbel, nbe)

 MASS = 9.10956d-31

 EV = 1.602176d-19

 FOR ie=0,nbe-1 DO BEGIN

 FOR iel=0,nbel-1 DO BEGIN

 FOR iaz=0,nbaz-1 DO BEGIN

 raw = distribution[solid[iel,iaz],ie,iline] / sector[iel,iaz]

 eff = efficency[iaz,iel,ie]

 IF eff EQ -1e31 THEN CONTINUE

 fg = geom\_factor[iaz,iel,ie]

 IF fg EQ -1e31 THEN CONTINUE

 E = energy[ie,1,notable[iline]]

 count[iaz,iel,ie,iline] = raw

 ; PHASE SPACE DENSITY in sec^3 / km^6

 psd[iaz,iel,ie,iline] = raw \* MASS \* MASS \* 1e18 / (dt \* eff \* fg \* 2 \* E \* E \* EV \* EV)

 END

 END

 END

 END

 stop

END

Below is a list of variables included in the SWEA 3D distribution Level 1 CDF files:

Epoch: the (center) time of each SWEA 3D distribution

SWEADistInterval: the length or time interval of each data point in seconds

SWEAModeID: the mode ID for each data point. The modes (0 and 1) are described in detail in the sections above and allow one to determine the energy bin values

Angle\_Bins: a simple array of values (0 – 79) assigned to each angle bin for convenience

Distribution: the SWEA 3D distribution in uncompressed counts

V0 : an adjustable setting for the instrument providing a kind of bias voltage to the instrument not used in practice due to the instrument charging effect discovered after launch

Distribution\_LABL\_1: a set of 16 dummy labels for the 16 energy bins of the distribution (done for convenience)

Distribution\_LABL\_2: a set of 80 dummy labels for the 80 angle bins of the distribution (done for convenience)

Energy: a simple array of values (1-16) assigned to each energy bin for convenience

Code used for plotting SWEA pitch angle distributions and spectra can be found on the STEREO/IMPACT website and will soon be archived in the SolarSoft software library.

For example, the STEREO Ahead pitch angle distributions are plotted in these routines:

<http://stereo.ssl.berkeley.edu/stereo_idl/sta_summ_plot_new.pro>

<http://stereo.ssl.berkeley.edu/stereo_idl/stb_summ_plot_new.pro>

These IMPACT plotting routines rely on the SPEDAS software library found here:

<http://themis.ssl.berkeley.edu/software.shtml>

# Error Analysis and Corrections

The standard deviation being the square root of the counts, +/- 1 sigma gives a confidence level of 68% and +/- 3  sigma gives 99%. Other errors come from the detector itself, for example from the non-concentricity of the spheres which slightly modulates the measured energy and the geometrical factor.

Another error comes from the MCP efficiency, which is energy dependent, however because the electrons are post-accelerated up to several hundreds of eV, this error is weak as the efficiency is almost constant over the reduced energy range of SWEA. Dead-time of the chain MCP+electronic produces errors at high count rates. This error can be corrected. This error is in the form:

y=x/(1-xt)

Where y is the true count rate, x, the measured one and t the dead time. The maximum measurable count rate is 1/t.

The dead-time was measured preflight using the procedure described below:



Figure 1: Setup for MCP characterization. The pencil beam is directed either to the MCP or to small aperture CEM. The gun has been moved in vertical and horizontal direction. The beam intensity was controlled by the total current of the gun cylinder and by CEM. Beam dynamic range is 103.

Setup for MCP characterization is shown in Figure 1. The vertical slit of the electron gun was closed by a screen with pin-hole to create a thin electron beam. The gun can move along *Y* and *Z* to illuminate each MCP sector. The total electron flow in the beam is *Jbeam* = *Jmeas* 0*.*0127. Here *Jmeas* is the current on the gun cylinder meas red by electrometer. The profile of the beam intensity at the MCP surface is shown in Figure 2.



Figure 2: **Y** (left panel) and **Z** (right panel) normalized profiles of the beam intensity.

Spatial distribution of electron flow produced by the gun does not change when total flow is increasing. We can use this gun property to measure the MCP dead-time. Two different MCP sector has been illuminated by pencil beam of different intensity. The method of measurements is as follows:

1. The beam flux varied from 4 · 103s−1 up to 8 · 104s−1
2. For each beam intensity the MCP count was recorded. The count profile was normalized assuming that the dead-time effect is neglidgable at the low countrate.



Figure 3: Selected sectors count versus MCPHV[V]. Vertical dashed line shows the working point for the subsequent calibration.

3. Since we know the beam distribution, we can simulate the total MCP count for various

deadtime *τ* values. Then we find the *τ* corresponding to the best fit to the experimental profile.

In the simple dead-time model the count rate is:



Here τ is the dead-time of the channel and Φ is the channel load. In the simulation, the appropriate number of the channels were loaded by corresponding Φ. Then the Count of each channel were summarized. Figure 4 shows the results of measurements and fitting. The simulation curve corresponds to



This in turn corresponds to the one bin (azimuthal sector) dead time 2.8e-6 s.



Figure 4: Two MCP channel normalized count rate ersus incident total rate of electrons. The black curve show the simulation curve for τ = 0.2s.

# Calibration and Validation

## Calibration

### Pre-flight/On-ground Calibration

The on-ground, pre-flight calibrations have been performed in the Institut de Recherche en Astrophysique et Planétologie (IRAP) facilities, using an electron gun in a vacuum chamber. The beam thickness was negligible and had a stability of 10%. The calibrations consisted in detailed characterization of the geometric factor and angular and energy responses. MCP gain and dead-time were also characterized using an electron beam.

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **Quantity** | **Methods** | **Results** | **Comments** | **Data Products Affected** |
| Energy/Angle  | Electron beam Energy-theta response of instrument | Energy resolution: 0.176 Angular resolution: - 22.5° in azimuth. - on average 10° intrinsic in elevation |  As planned |  All     |
| Geometric factor | Electron beam Energy-theta response of instrument | Smooth energy and angular response.K factor ~ 6.36 Geo. factor at 0° of ~ 3.32E-02 cm² sr eV / eV |  As planned |  All |
| MCP efficiency |  Vertical and horizontal steering of electron beam to characterrize all MCP sectors |  Calibrations made with MCP voltage of 2800 V. MCP efficiency 0.83Deadtime of ordrer 130 ms. |  As planned |  All |
|   |   |   |   |   |

### In-flight Calibration

In flight calibrations were performed using SWEA observations at energies between 100 and 250 eV in the strahl energy range. The reasons were that the instrument response was altered at lower energies due to electrostatic charging of the top cap at the entrance of the instrument. The inter-anode calibrations have consisted in the use of measurements at the same energies and same pitch-angles over large time intervals at several periods during the mission. Absolute calibrations have been made using measurements by other spacecraft at L1.

|  |  |  |
| --- | --- | --- |
| **Quantity** | **Methods** | **Data Products Affected** |
| Moments | Comparisons with L1 data | Moments |
| Angular / pitch angle response | Strahl comparisons with B field | PADs |
| Energy Spectra | Comparisons with L1 data | Spectra |
|  |   |   |

## Validation

### Comparisons with L1 electron measurements (WIND, ACE) in scientific analyses

Our data validations on IMPACT team are routinely carried out via application of the measurements to scientific analyses, often using comparisons with similar measurements at the L1 location upstream of Earth on WIND and/or ACE. These studies are led by both IMPACT team members and non-members. A selection of results that demonstrate the SWEA performance are given in the references by Yu et al. (2014), Liu et al. (2014), Moestl et al. (2012, and Nieves-Chinchilla et al. (2011). These describe the use of the SWEA data to analyze small-scale to large scale transient structures which have been shown to include counter-streaming electrons as a signature of closed magnetic structures in the solar wind. Studies of these types of events at L1 are complemented by the STEREO observations at a separated location. SWEA observations also have the advantage of being clear of the Earth’s foreshock where Earth ‘contaminates’ the interplanetary signature.

### Inter-Comparisons between STEREO-A and –B in scientific analyses

Intercomparisons of STEREO IMPACT SWEA results also provide a unique opportunity to compare the electrons seen by nearly identical instruments on two separated spacecraft effectively in Earth’s orbit. Studies described by Opitz et al. (2010), Lavraud et al. (2010), Simunac et al. (2012), and Louarn et al. (2009) provide some examples. These comparisons are uniquely suited to timing studies and detailed comparisons because there are minimal instrumental differences involved. They show that for all practical purposes the two SWEAs on STEREO A and B are the same. (Note: STEREO-B contact was lost in October 2014, so the STEREO-B SWEA data, and thus these highly comparable observations, are only available from early 2007 to that date.)

# References

Lin, R.P. , et al., A three-dimensional plasma and energetic particle investigation for the WIND spacecraft, Space Science Reviews 71: 125-153, 1995.

Carlson et al., The electron and ion plasma experiment for FAST, Space Science Reviews 98: 33–66, 2001.

Sauvaud, J.A. et al., The IMPACT Solar Wind Electron Analyzer, Space Sci. Rev., 136, 227-239, 2008

Fedorov, A. et al., The IMPACT Solar Wind Electron Analyzer (SWEA):Reconstruction of the SWEA Transmission Function by Numerical Simulation and Data Analysis, Space Science Rev., 161, 49-62, 2011.

Lavraud, B. et al., Statistics of counterstreaming solar wind suprathermal electrons at solar minimum: STEREO observations, Ann Geophys., 28, 233-246, 2010.

Louarn, P. et al., On the temporal variability of the Strahl and its relationship with solar wind characteristics: STEREO SWEA observations, Solar Phys. 259, 311-321, 2009.

Opitz, A. et al., Temporal Evolution of the Solar-Wind Electron Core Density at Solar Minimum by Correlating SWEA Measurements from STEREO A and B, Solar Phys., 266, 369-377, 2010.

Moestl, C. et al., Multi-point shock and flux rope analysis of multiple interplanetary coronal mass ejections around 2010 August 1 in the inner heliopshere, Astrophy. J., 758(10), doi:10.1088/0004-637X/758/1/10, 2012.

Simunac K.D.C., Galvin A.B., Farrugia C.F., Kistler L.M., Kucharek H., Lavraud B., Liu Y.C.-M., Luhmann J. G., Ogilvie K.W., OpitzA., Popecki M.A., Sauvaud J-A., andWang S. The heliospheric plasma sheet observed in situ by 3 spacecraft over 4 solar rotations Solar Physics, 281(1), 423-447, doi: 10.1007/s11207-012-0156-9, 2012

Nieves-Chinchilla T., Gomez-Herrero R., Vinas A. F., Malandraki O., Dresing N., Hidalgo M. A., OpitzA., Sauvaud J-A., Lavraud B., and Davila J. M. Analysis and study of the in situ observation of the June 1st 2008 CME by STEREO J. Atmos. Solar-Terr. Phys.(ILWS), vol. 73, p1348, 2011.

Yu, W. et al., A statistical analysis of properties of small transients in the solar wind 2007–2009: STEREO and Wind observations, J. Geophys. Res. Space Physics, 119, 689–708, doi:10.1002/2013JA019115,2014.

Liu, Y.C. et al., Statistical Analysis of Heliospheric Plasma Sheets, Heliospheric Current Sheets and Sector Boundaries Observed in situ by STEREO, J. Geophys. Res., DOI: 10.1002/2014JA019956,2014.