;+
;PROCEDURE:	load_sta_2_het
;PURPOSE:	
;   loads STEREO/IMPACT HET Level 2 15 min resolution data for "tplot".
;
;INPUTS:	none, but will call "timespan" if time
;		range is not already set.
;KEYWORDS:
;  TIME_RANGE:  2 element vector specifying the time range
;  DATA:        Data returned in this named variable.
;  NODATA:	Returns 0 if data exists for time range, otherwise returns 1.
;  PREFIX:	(string) prefix for tplot variables.  Default is 'sta_'
;  NAME:	(string) name for tplot variables. Default is 'sta_let'
;  MASTERFILE:	(string) full filename of master file.
;SEE ALSO: 
;  "make_cdf_index","loadcdf","loadcdfstr","loadallcdf"
;
;CREATED BY:	Peter Schroeder
;LAST MODIFIED:	05/22/08
;-


pro load_sta_l2_het,time_range=trange,data=d,  $
  nodata=nodat, $
  prefix = prefix, $
  name = bname, $
  masterfile=masterfile, novardata=nvd
  
myformat = '/disks/stereodata/sepdata/HET/Ahead/15minute/'
restore,'/home/peters/stereo/idl/hettemplate.idlsave'

nodat = 0

get_timespan,time_array

timestrs = time_struct(time_array)

timelen = long((time_array[1] - time_array[0])/60d/15d + 6000d)

hetdatastr = { $
   time: 0d, $
   e_intensity: fltarr(3), $
   e_sigma: fltarr(3), $
   h_intensity: fltarr(11), $
   h_sigma: fltarr(11) }

full_data_array = replicate(hetdatastr,timelen)
full_cnt = -1l

ms = ['','Jan','Feb','Mar','Apr','May','Jun','Jul','Aug','Sep','Oct','Nov','Dec']

for year=timestrs[0].year, timestrs[1].year do begin
   if year eq timestrs[0].year then minmonth = timestrs[0].month else $
      minmonth = 1
   if year eq timestrs[1].year then maxmonth = timestrs[1].month else $
      maxmonth = 12

   yearstr = strmid(strcompress(year,/rem),2,2)
   
   for month = minmonth, maxmonth do begin
      data_array = 0
      count = 0
      monthstr = ms[month]
      fname = 'AeH'+yearstr+monthstr+'.15m'
      fullname = myformat+fname
      print,'Loading '+fullname
      data_array = read_ascii(fullname,template=het_template,count=count)
      if count ne 0 then begin
         if month lt 10 then mmonthstr = '0'+strcompress(month,/rem) else $
            mmonthstr = strcompress(month,/rem)
         timepre = '20'+yearstr+'-'+mmonthstr+'-'
         
         for cnt = 0,count-1 do begin
            full_cnt += 1l
            thisday = data_array.day[cnt]
            if thisday lt 10 then mdaystr = '0'+strcompress(thisday,/rem) else $
               mdaystr = strcompress(thisday,/rem)
            thistime = data_array.time[cnt]
            mhrstr = strcompress(strmid(thistime,0,2),/rem)
            mminstr = strcompress(strmid(thistime,2,2),/rem)
            td = time_double(timepre+mdaystr+'/'+mhrstr+':'+mminstr)
            
            full_data_array[full_cnt].time = td
            full_data_array[full_cnt].e_intensity = [data_array.e1[cnt], $
            data_array.e2[cnt], data_array.e3[cnt]]
            full_data_array[full_cnt].e_sigma = [data_array.e1sigma[cnt], $
               data_array.e2sigma[cnt],data_array.e3sigma[cnt]]
            full_data_array[full_cnt].h_intensity=[data_array.h1[cnt], $
               data_array.h2[cnt],data_array.h3[cnt],data_array.h4[cnt], $
               data_array.h5[cnt],data_array.h6[cnt],data_array.h7[cnt], $
               data_array.h8[cnt],data_array.h9[cnt],data_array.h10[cnt], $
               data_array.h11[cnt]]
            full_data_array[full_cnt].h_sigma=[data_array.h1sigma[cnt], $
               data_array.h2sigma[cnt],data_array.h3sigma[cnt], $
               data_array.h4sigma[cnt],data_array.h5sigma[cnt], $
               data_array.h6sigma[cnt],data_array.h7sigma[cnt], $
               data_array.h8sigma[cnt],data_array.h9sigma[cnt], $
               data_array.h10sigma[cnt], data_array.h11sigma[cnt]]
         endfor
      endif
   endfor
endfor

full_data_array = full_data_array[0:full_cnt]

store_data,'sta_l2_het',data=full_data_array

if keyword_set(full_cnt) le 0 then begin
   message,'No STA HET data during this time.',/info
   nodat = 1
  return
endif

e_energies = [0.7,1.4,2.8]
H_energies = [13.6,14.9,17.0,20.8,23.8,26.3,29.5,33.4,35.5,40.0,60.0]

data = full_data_array

end